Требования к баннерам |
ГеобаннерОписаниеFlash-баннер с несколькими ссылками для клика в зависимости от географической зоны посетителя. По клику на баннер происходит переход в определённый раздел сайта, соответствующий географической зоне посетителя. Ссылки для клика хранятся в XML-файле, который подгружается в баннер. XML-файл загружается в AdRiver. ID геозон в AdRiver. Программный код Ваш рекламный код не должен обращаться к внешнему серверу для выполнения дополнительных скриптов JavaScript. Все функции должны быть реализованы в самом коде. Во flash-ролик системой AdRiver передается значение параметра «ar_geoid». Оно соответствует геозоне посетителя сайта, просматривающего баннер. Чтобы получить этот параметр, следует использовать следующий скрипт: для AS2: var ar_geoid:String = _root.ar_geoid; для AS3: var ar_geoid:String = LoaderInfo(this.root.loaderInfo).parameters['ar_geoid']; Параметр ar_geoid может применяться для геотаргетинга в баннере. Например, можно организовать переход по клику в зависимости от геозоны посетителя, выполнившего клик http://www.adriver.ru/doc/ban/geo/. Подготовка гео-баннера 1. Подготовка баннера 1.1. Flash-ролик Скачайте пример комплекта файлов для баннера. Во flash-ролике пропишите следующий ActionScript: Пример кода на AS2: if(_root.ar_comppath==undefined) _root.ar_comppath="";
on(release){
if (_root.ar_pass){
var temp_mc = _root.createEmptyMovieClip("temp_mc", _root.getNextHighestDepth());
temp_mc._x = -10000;
var mcLoader = new MovieClipLoader();
mcLoader.addListener({onLoadInit:function(mc:MovieClip){
mcLoader.unloadClip(mc);
}});
mcLoader.loadClip(_root.ar_pass, temp_mc);
}
getURL(_root.link1+escape(_root.ar_click_href), "_blank");
}
// Geographical zone must be defined and be not Inter-regional networks
if(ar_geoid!=0&&ar_geoid!=81){
menu_xml = new XML();
menu_xml.ignoreWhite = true;
menu_xml.onLoad = function (ok){
if (ok) {
var num_items = this.childNodes.length;
var f = this.firstChild.firstChild;
do{
trace(f.attributes.id);
if(f.attributes.id==_root.ar_geoid){
_root.ar_click_href=f.attributes.click;
break;
}
}while(f=f.nextSibling);
return;
}
}
menu_xml.load(_root.ar_comppath + "things.xml");
}
// In case there are some errors the target link is default
if(_root.ar_click_href==undefined) _root.ar_click_href="";
Описание:
Пример кода на AS3: var xml:XML;
var ar_geoid:String = LoaderInfo(this.root.loaderInfo).parameters['ar_geoid']||"";
var ar_comppath:String = LoaderInfo(this.root.loaderInfo).parameters['ar_comppath']||"";
var ar_click_href = "";
XML.ignoreWhitespace = true;
if (ar_geoid!="0"&&ar_geoid!="81"){
var loader:URLLoader = new URLLoader();
loader.dataFormat = URLLoaderDataFormat.TEXT;
loader.addEventListener(Event.COMPLETE, urlLoader_complete);
loader.load(new URLRequest(ar_comppath+"things.xml"));
function urlLoader_complete(e:Event):void {
xml = new XML(e.target.data);
var f = xml.*;
for each(var t in f){
if (t.@id==ar_geoid){
ar_click_href=t.@click;
break;
}
}
}
}
Для элемента button пропишите следующий код: on(release){
if (_root.ar_pass){
var temp_mc = _root.createEmptyMovieClip("temp_mc", _root.getNextHighestDepth());
temp_mc._x = -10000;
var mcLoader = new MovieClipLoader();
mcLoader.addListener({onLoadInit:function(mc:MovieClip){
mcLoader.unloadClip(mc);
}});
mcLoader.loadClip(_root.ar_pass, temp_mc);
}
getURL(_root.link1+escape(_root.ar_click_href), "_blank");
}
Для ActionScript3: function callLink(event:MouseEvent):void {
var pass:String = LoaderInfo(this.root.loaderInfo).parameters['ar_pass'];
if(pass&&pass!="undefined") (new Loader()).load(new URLRequest(pass));
var url:String = LoaderInfo(this.root.loaderInfo).parameters['link1']+escape(ar_click_href);
try {
var ie:String = ExternalInterface.call("function(){return !!window.ActiveXObject}");
if (ie == "true") ExternalInterface.call('window.open',url);
else navigateToURL(new URLRequest(url), '_blank');
}catch (e:Error){
navigateToURL(new URLRequest(url), '_blank');
}
}
click_btn.addEventListener(MouseEvent.CLICK, callLink);
1.2. XML-файл Пример XML-файла: <root> <item id="33" region="Спб" click="http://www.timeout.ru/?city=3"/> <item id="40" region="Новосибирская область" click="http://www.timeout.ru/?city=6"/> <item id="30" region="Красноярская область" click="http://www.timeout.ru/?city=7"/> <item id="38" region="Москва" click="http://www.timeout.ru/?city=2"/> </root> Описание:
|